---

MSDE FunClub		最終更新日 : 2000/11/23
Microsoft Data Engine FunClub	Since 2000.11.23
SQLServer7.0/MSDE 完全トレーニングテキスト（下巻）
【第２３章４７６ｐ 〜 ４７７ｐ掲載】

---

Accessプロジェクトのフォーム一覧
ウィザードを起動して下さい

医師テーブルを選択する

「次へ」ボタンを押してフォームを作成します

[調査]ボタンを配置した医師フォーム

[調査]ボタンを押して、フォームのプロパティの表示

【フォームモジュールに組み込むプログラム】

'
'フォームに連結されたレコードセットなどの情報を表示します
'
Private Sub CMDRS_Click()
    ShowRs Me
End Sub


【標準モジュールに組み込むプログラム】

'
'***************************************
'フォームのレコードセットプロパティの表示
'***************************************
'
Public Sub ShowRs(fm As Form)
    Dim rs As ADODB.Recordset
    Dim St$, cl$, ct$, rt$, lk$
    
    'フォームのADOレコードセットを取得
    Set rs = fm.Recordset
    If rs Is Nothing Then
       MsgBox "レコードセットは未定義です(Nothing)", , "非連結状態"
       Exit Sub
    End If
    
    'カーソル位置
    If rs.CursorLocation = adUseClient Then
       cl = "adUseClient"
    ElseIf rs.CursorLocation = adUseServer Then
       cl = "adUseServer"
    End If
    
    'カーソルタイプ
    Select Case rs.CursorType
    Case adOpenForwardOnly
         ct = "adOpenForwardOnly"
    Case adOpenKeyset
         ct = "adOpenKeyset"
    Case adOpenDynamic
         ct = "adOpenDynamic"
    Case adOpenStatic
         ct = "adOpenStatic"
    End Select
     
    'ロックタイプ
    Select Case rs.LockType
    Case adLockReadOnly
         lk = "adLockReadOnly"
    Case adLockPessimistic
         lk = "adLockPessimistic"
    Case adLockOptimistic
        lk = "adLockOptimistic"
    Case adLockBatchOptimistic
        lk = "adLockBatchOptimistic"
    End Select

    'フォームのRecordsetType
    Select Case fm.RecordsetType
    Case 3
         rt = "Snapshot"
    Case 4
         rt = "Updatable Snapshot"
    End Select
    
    
    St = " RecordSource   = " & fm.RecordSource & vbCrLf & _
         " RecordType     = " & rt & vbCrLf & _
         " UniqueTable    = " & fm.UniqueTable & vbCrLf & _
         " ResyncCommand  = " & fm.ResyncCommand & vbCrLf & _
         " CursorLocation = " & cl & vbCrLf & _
         " CursorType     = " & ct & vbCrLf & _
         " LockType       = " & lk & vbCrLf & _
         " CacheSize      = " & rs.CacheSize & vbCrLf & _
         " Connection     = " & rs.ActiveConnection.ConnectionString
         
    MsgBox St, , "[" & fm.Name & "] フォームのプロパティ"
End Sub

下巻：ISBN4-7741-0966-5

ウィンドウを閉じる

---

（株）日本技術ソフト開発　責任編集：堀川　明
MSDE FunClubに関するご意見・ご要望等ございましたら、 msdefun@horikawa.ne.jp　までご連絡下さい。
HOME: http://www.horikawa.ne.jp/msde/

---

MSDE FunClubの運営は、マイクロソフト社とは一切の関係はありません